Codemasters Artwork Disc ECTS 2000 ( UK)/Codemasters - Artwork Disc ECTS 2000 (UK).bin/pc/main.dxr/00082_repeat film loop.ls

Text File | 2000-01-01 | 1.6 KB | 45 lines

property spriteNum, myCounter, myLength, myRepetitions, myTotal

on beginSprite me
  myCounter = 0
  myTotal = myLength * myRepetitions
end

on exitFrame me
  myCounter = myCounter + 1
  if myCounter < myTotal then
    go(the frame)
  end if
end

on getPropertyDescriptionList me
  CheckSpriteType(me)
  theProps = [:]
  c = "How many frames long is this filmloop?"
  f = #integer
  addProp(theProps, #myLength, [#comment: c, #format: f, #default: 30])
  c = "How many repetitions before advancing?"
  f = #integer
  addProp(theProps, #myRepetitions, [#comment: c, #format: f, #default: 3])
  return theProps
end

on getBehaviorDescription me
  line1 = "   This behavior can be dragged onto a filmloop so that it will repeat a given number of times." & RETURN
  line2 = "   You'll need to tell it how many frames were used to make up the filmloop, as well as how many times you'd like it to repeat."
  line3 = " The movie will hold on the first frame of this filmloop sprite until it plays as many repetitions as you specify. " & RETURN
  line4 = "   (You can shrink the filmloop down to a single frame if you wish to see only that precise number of repetitions,"
  line5 = " or you can tween the rest of the filmloop out if it doesn't matter how much more of the filmloop is seen after the required number of repetitions.)"
  return line1 & line2 & line3 & line4 & line5
end

on CheckSpriteType me
  thisSprite = the currentSpriteNum
  if thisSprite <> 0 then
    if (the member of sprite thisSprite).type <> #filmLoop then
      alert("Sorry, this 'Filmloop Counter' behavior can only be used on filmloops.")
      abort()
    end if
  end if
end